GNU bug report logs - #19106
M-x eww: use the current URI as the default; be bound to a key

Previous Next

To add a comment to this bug, you must first unarchive it, by sending
a message to control AT debbugs.gnu.org, with unarchive 19106 in the body.
You can then email your comments to 19106 AT debbugs.gnu.org in the normal way.

Toggle the display of automated, internal messages from the tracker.

Message #5 received at submit <at> debbugs.gnu.org (full text, mbox):

From: Ivan Shmakov <ivan <at> siamics.net>
To: submit <at> debbugs.gnu.org
Subject: M-x eww: use the current URI as the default; be bound to a key 
Date: Wed, 19 Nov 2014 12:01:56 +0000

[Message part 1 (text/plain, inline)]

Package:  emacs
Severity: wishlist

	The patch MIMEd makes ‘eww’ use the currently browsed URI as the
	default while prompting.  One of the consequences is that it’s
	now possible for the user to use M-n (or <down>) to get one, and
	feed it back to EWW after editing as necessary.

	I also suggest to bind the ‘eww’ command to ‘G’ in eww-mode-map,
	for both it’s a sane mnemonic (“Go to”), and also given that
	this behavior is rather similar to the Lynx ECGOTO command,
	bound to ‘G’ in its default keymap.

	Also to note is that M-x eww currently does /not/ call
	eww-save-history, and simply “forgets” the page currently
	visited.  I use a workaround for that, but have no sane fix to
	suggest right now.

-- 
FSF associate member #7257  http://boycottsystemd.org/  … 3013 B6A0 230E 334A

[Message part 2 (text/diff, inline)]

--- a/lisp/net/eww.el
+++ b/lisp/net/eww.el
@@ -159,9 +203,14 @@
 ;;;###autoload
 (defun eww (url)
   "Fetch URL and render the page.
 If the input doesn't look like an URL or a domain name, the
 word(s) will be searched for via `eww-search-prefix'."
-  (interactive "sEnter URL or keywords: ")
+  (interactive
+   (let* ((uri (plist-get eww-data :url))
+	  (prompt (concat "Enter URL or keywords"
+			  (if uri (format " (default %s)" uri) "")
+			  ": ")))
+     (list (read-string prompt nil nil uri))))
   (setq url (string-trim url))
   (cond ((string-match-p "\\`file:/" url))
 	;; Don't mangle file: URLs at all.
@@ -513,6 +568,7 @@ the like."
     (suppress-keymap map)
     (define-key map "q" 'quit-window)
     (define-key map "g" 'eww-reload)
+    (define-key map "G" 'eww)
     (define-key map [?\t] 'shr-next-link)
     (define-key map [?\M-\t] 'shr-previous-link)
     (define-key map [delete] 'scroll-down-command)

Message #8 received at 19106 <at> debbugs.gnu.org (full text, mbox):

From: Tassilo Horn <tsdh <at> gnu.org>
To: Ivan Shmakov <ivan <at> siamics.net>
Cc: 19106 <at> debbugs.gnu.org
Subject: Re: bug#19106: M-x eww: use the current URI as the default;
 be bound to a key
Date: Wed, 19 Nov 2014 13:17:39 +0100

Ivan Shmakov <ivan <at> siamics.net> writes:

> 	The patch MIMEd makes ‘eww’ use the currently browsed URI as the
> 	default while prompting.

It would also be neat if M-x eww RET would use the URL at point as a
default (at least in non-eww buffers).  I've not set up eww as default
browse-url browser, but for some URLs (e.g., in info docs or emails) I'd
like to have a quick way to browse them with eww instead of my default
browser.

Bye,
Tassilo

Message #11 received at 19106 <at> debbugs.gnu.org (full text, mbox):

From: Ivan Shmakov <ivan <at> siamics.net>
To: 19106 <at> debbugs.gnu.org
Subject: Re: bug#19106: M-x eww: use the current URI as the default;
 be bound to a key
Date: Wed, 19 Nov 2014 13:31:34 +0000

>>>>> Tassilo Horn <tsdh <at> gnu.org> writes:
>>>>> Ivan Shmakov <ivan <at> siamics.net> writes:

 >> The patch MIMEd makes ‘eww’ use the currently browsed URI as the
 >> default while prompting.

 > It would also be neat if M-x eww RET would use the URL at point as a
 > default (at least in non-eww buffers).  I've not set up eww as
 > default browse-url browser, but for some URLs (e. g., in info docs or
 > emails) I'd like to have a quick way to browse them with eww instead
 > of my default browser.

	This also makes sense, indeed.  Perhaps we should either provide
	yet another user-settable option for that (what about
	eww-default-uri-hook – to be run -until-success – for
	instance?), or provide /two/ separate commands for these two
	behaviors.  Or even three, as it’s perfectly possible to stumble
	on the case where the text under point is a valid URI, but lacks
	an associated shr-url property (think of browsing a text/plain
	Web page, for instance), or has it different to the text itself.

	The eww-default-uri-hook solution seems reasonably easy to
	implement; I hope to suggest a possible patch later.

-- 
FSF associate member #7257  http://boycottsystemd.org/  … 3013 B6A0 230E 334A

Message #14 received at 19106 <at> debbugs.gnu.org (full text, mbox):

From: Ivan Shmakov <ivan <at> siamics.net>
To: 19106 <at> debbugs.gnu.org
Subject: Re: bug#19106: M-x eww: use the current URI as the default;
 be bound to a key 
Date: Wed, 19 Nov 2014 14:37:14 +0000

[Message part 1 (text/plain, inline)]

>>>>> Ivan Shmakov <ivan <at> siamics.net> writes:

[…]

 > The eww-default-uri-hook solution seems reasonably easy to implement;
 > I hope to suggest a possible patch later.

	Better still, we can support all the options at the same time
	simply by passing a list to read-string, as per the revised
	patch MIMEd.

	One may still wish to customize the order of the entries listed,
	or perhaps to add new ones (think of recognizing, say, RFC 7154
	or RFC7154 as a link to http://tools.ietf.org/html/rfc7154, for
	instance), but to be convenient, there should probably be a
	couple of helper functions to correspond to the lambdas in the
	example code fragment also MIMEd.

-- 
FSF associate member #7257  http://boycottsystemd.org/  … 3013 B6A0 230E 334A

[Message part 2 (text/diff, inline)]

--- a/lisp/net/eww.el
+++ b/lisp/net/eww.el
@@ -29,6 +29,7 @@
 (require 'shr)
 (require 'url)
 (require 'url-queue)
+(require 'url-util)			; for url-get-url-at-point
 (require 'mm-url)
 (eval-when-compile (require 'subr-x)) ;; for string-trim
 
@@ -158,12 +159,29 @@
     (define-key map "\r" 'eww-follow-link)
     map))
 
+(defun eww-suggested-uris nil
+  "Return the list of URIs to suggest at the `eww' prompt."
+  ;; FIXME: allow for customization?
+  (remq nil
+	(list ;; in the shr-copy-url order
+	      (get-text-property (point) 'shr-url)
+	      (get-text-property (point) 'image-url)
+	      ;; check the text itself
+	      (url-get-url-at-point)
+	      ;; fallback to the URI of the visited page
+	      (plist-get eww-data :url)))
+
 ;;;###autoload
-(defun eww (url)
+(defun eww (url &optional no-save-history)
   "Fetch URL and render the page.
 If the input doesn't look like an URL or a domain name, the
 word(s) will be searched for via `eww-search-prefix'."
-  (interactive "sEnter URL or keywords: ")
+  (interactive
+   (let* ((uris (eww-suggested-uris))
+	  (prompt (concat "Enter URL or keywords"
+			  (if uris (format " (default %s)" (car uris) ""))
+			  ": ")))
+     (list (read-string prompt nil nil uris))))
   (setq url (string-trim url))
   (cond ((string-match-p "\\`file:/" url))
 	;; Don't mangle file: URLs at all.
@@ -513,6 +526,7 @@ the like."
     (suppress-keymap map)
     (define-key map "q" 'quit-window)
     (define-key map "g" 'eww-reload)
+    (define-key map "G" 'eww)
     (define-key map [?\t] 'shr-next-link)
     (define-key map [?\M-\t] 'shr-previous-link)
     (define-key map [delete] 'scroll-down-command)

[Message part 3 (text/emacs-lisp, inline)]

(require 'cl-seq)                       ; for cl-reduce

(defcustom eww-suggest-uris
  '((lambda ()
      (list (get-text-property (point) 'shr-url)
            (get-text-property (point) 'image-url)))
    'url-get-url-at-point
    (lambda ()
      (plist-get eww-data :url)))
  "List of functions called to form the list of default URIs for `eww'.
Each of the elements is a function returning either a string or a list
of strings.  The results will be joined into a single list with
duplicate entries (if any) removed."
  :version "25.1"
  :group 'eww
  :type 'hook)

(defun eww-suggested-uris nil
  "Return the list of URIs to suggest at the `eww' prompt.
This list can be customized via `eww-suggest-uris'."
  (let ((obseen (make-vector 42 0)))
    (cl-reduce (lambda (acc elt)
                 (let ((uri (funcall elt)))
                   (if (or (not acc) (intern-soft uri obseen))
                       acc
                     (intern uri obseen)
                     (cons uri acc))))
               eww-suggest-uris
               :initial-value nil)))

Message #17 received at submit <at> debbugs.gnu.org (full text, mbox):

From: Mark Oteiza <mvoteiza <at> udel.edu>
To: bug-gnu-emacs <at> gnu.org
Subject: Re: bug#19106: M-x eww: use the current URI as the default;
 be bound to a key
Date: Wed, 19 Nov 2014 12:09:08 -0500

Ivan Shmakov <ivan <at> siamics.net> writes:

> Package:  emacs
> Severity: wishlist
>
> 	The patch MIMEd makes ‘eww’ use the currently browsed URI as the
> 	default while prompting.  One of the consequences is that it’s
> 	now possible for the user to use M-n (or <down>) to get one, and
> 	feed it back to EWW after editing as necessary.
>
> 	I also suggest to bind the ‘eww’ command to ‘G’ in eww-mode-map,
> 	for both it’s a sane mnemonic (“Go to”), and also given that
> 	this behavior is rather similar to the Lynx ECGOTO command,
> 	bound to ‘G’ in its default keymap.

In elinks, ‘g’ is used for an empty “go to” prompt, and ‘G’ is used for
prompt populated with the current URL.  In many other places, ‘o’ and
‘O’ are used (“open”), respectively.  These places would be the firefox
addons vimperator or pentadactyl, and a number of keyboard driven webkit
browsers, though this is because they are vim-oriented so g/G are
already used.  I think the ‘o’ ‘O’ mnemonic is nice as well, and these keys
are free in eww.

Message #20 received at 19106 <at> debbugs.gnu.org (full text, mbox):

From: Lars Magne Ingebrigtsen <larsi <at> gnus.org>
To: Ivan Shmakov <ivan <at> siamics.net>
Cc: 19106 <at> debbugs.gnu.org
Subject: Re: bug#19106: M-x eww: use the current URI as the default;
 be bound to a key
Date: Wed, 19 Nov 2014 18:31:05 +0100

Ivan Shmakov <ivan <at> siamics.net> writes:

> Better still, we can support all the options at the same time
> simply by passing a list to read-string, as per the revised
> patch MIMEd.

Isn't the recommended way to supply defaults to functions like this to
stash it in `M-p'?

-- 
(domestic pets only, the antidote for overdose, milk.)
   bloggy blog: http://lars.ingebrigtsen.no

Message #23 received at 19106 <at> debbugs.gnu.org (full text, mbox):

From: Ivan Shmakov <ivan <at> siamics.net>
To: 19106 <at> debbugs.gnu.org
Subject: Re: bug#19106: M-x eww: use the current URI as the default;
 be bound to a key 
Date: Wed, 19 Nov 2014 20:07:22 +0000

>>>>> Lars Magne Ingebrigtsen <larsi <at> gnus.org> writes:
>>>>> Ivan Shmakov <ivan <at> siamics.net> writes:

 >> Better still, we can support all the options at the same time simply
 >> by passing a list to read-string, as per the revised patch MIMEd.

 > Isn't the recommended way to supply defaults to functions like this
 > to stash it in `M-p'?

	I do not copy.  Care to provide an example of such a function?

	(M-p?  Did you, by a chance, mean M-n instead?  At the very
	least, C-x C-f has M-n to get buffer-file-name into the
	minibuffer.  And it’s exactly how either of my patches behave.)

-- 
FSF associate member #7257  np. Blücher — Kamelot       … 3013 B6A0 230E 334A

Message #26 received at 19106 <at> debbugs.gnu.org (full text, mbox):

From: Lars Magne Ingebrigtsen <larsi <at> gnus.org>
To: Ivan Shmakov <ivan <at> siamics.net>
Cc: 19106 <at> debbugs.gnu.org
Subject: Re: bug#19106: M-x eww: use the current URI as the default;
 be bound to a key
Date: Wed, 19 Nov 2014 21:27:16 +0100

Ivan Shmakov <ivan <at> siamics.net> writes:

> I do not copy.  Care to provide an example of such a function?
>
> (M-p?  Did you, by a chance, mean M-n instead?  At the very
> least, C-x C-f has M-n to get buffer-file-name into the
> minibuffer.  And it’s exactly how either of my patches behave.)

Er, yes, `M-n'.

I thought the patch had a "default (...)" thing instead?

-- 
(domestic pets only, the antidote for overdose, milk.)
   bloggy blog: http://lars.ingebrigtsen.no

Message #29 received at 19106 <at> debbugs.gnu.org (full text, mbox):

From: Ivan Shmakov <ivan <at> siamics.net>
To: 19106 <at> debbugs.gnu.org
Subject: Re: bug#19106: M-x eww: use the current URI as the default;
 be bound to a key 
Date: Wed, 19 Nov 2014 20:40:07 +0000

>>>>> Lars Magne Ingebrigtsen <larsi <at> gnus.org> writes:
>>>>> Ivan Shmakov <ivan <at> siamics.net> writes:

 >> I do not copy.  Care to provide an example of such a function?

 >> (M-p?  Did you, by a chance, mean M-n instead?  At the very least,
 >> C-x C-f has M-n to get buffer-file-name into the minibuffer.  And
 >> it’s exactly how either of my patches behave.)

 > Er, yes, `M-n'.

 > I thought the patch had a "default (...)" thing instead?

	The second patch has both.

	Specifically, when read-string is passed a (non-empty) list for
	its ‘default’ argument, the car of such list is used as the
	default value, while all the list elements are available for
	M-n, M-p.  The patch suggested just tries to make the “default
	value” part clear to the user:

+	  (prompt (concat "Enter URL or keywords"
+			  (if uris (format " (default %s)" (car uris) ""))
+			  ": ")))

-- 
FSF associate member #7257  http://boycottsystemd.org/  … 3013 B6A0 230E 334A

Message #32 received at 19106 <at> debbugs.gnu.org (full text, mbox):

From: Ivan Shmakov <ivan <at> siamics.net>
To: 19106 <at> debbugs.gnu.org
Subject: Re: bug#19106: M-x eww: use the current URI as the default;
 be bound to a key 
Date: Thu, 20 Nov 2014 13:45:06 +0000

>>>>> Mark Oteiza <mvoteiza <at> udel.edu> writes:
>>>>> Ivan Shmakov <ivan <at> siamics.net> writes:

 >> Package: emacs Severity: wishlist

 >> The patch MIMEd makes ‘eww’ use the currently browsed URI as the
 >> default while prompting.  One of the consequences is that it’s now
 >> possible for the user to use M-n (or <down>) to get one, and feed it
 >> back to EWW after editing as necessary.

 >> I also suggest to bind the ‘eww’ command to ‘G’ in eww-mode-map, for
 >> both it’s a sane mnemonic (“Go to”), and also given that this
 >> behavior is rather similar to the Lynx ECGOTO command, bound to ‘G’
 >> in its default keymap.

 > In elinks, ‘g’ is used for an empty “go to” prompt, and ‘G’ is used
 > for prompt populated with the current URL.

	My point is that with read-string, we don’t need to implement
	two distinct commands for that, – either of my patches provides
	an empty prompt on ‘G’, yet makes the current page’s URI
	(along with a few others, for the second patch) available upon a
	keystroke (M-n or <down>.)

[…]

-- 
FSF associate member #7257  http://boycottsystemd.org/  … 3013 B6A0 230E 334A

Message #35 received at 19106 <at> debbugs.gnu.org (full text, mbox):

From: Ivan Shmakov <ivan <at> siamics.net>
To: 19106 <at> debbugs.gnu.org
Subject: Re: bug#19106: M-x eww: provide default URIs; be bound to a key 
Date: Sat, 22 Nov 2014 19:20:34 +0000

[Message part 1 (text/plain, inline)]

>>>>> Ivan Shmakov <ivan <at> siamics.net> writes:

	Please consider the revised patch MIMEd.

[…]

 > One may still wish to customize the order of the entries listed, or
 > perhaps to add new ones (think of recognizing, say, RFC 7154 or
 > RFC7154 as a link to http://tools.ietf.org/html/rfc7154, for
 > instance), but to be convenient, there should probably be a couple of
 > helper functions to correspond to the lambdas in the example code
 > fragment also MIMEd.

	I’ve found that I myself prefer a different order for the
	default URIs than my previous patch suggested.  Therefore, I’ve
	ended up making it fully customizable.

-- 
FSF associate member #7257  np. Following My Father’s Song — Jami Sieber

[Message part 2 (text/diff, inline)]

--- a/lisp/net/eww.el	2014-11-21 09:21:50 +0000 
+++ b/lisp/net/eww.el	2014-11-22 19:05:15 +0000
@@ -29,6 +29,7 @@
 (require 'shr)
 (require 'url)
 (require 'url-queue)
+(require 'url-util)			; for url-get-url-at-point
 (require 'mm-url)
 (eval-when-compile (require 'subr-x)) ;; for string-trim
 
@@ -59,6 +60,21 @@
   :group 'eww
   :type 'string)
 
+(defcustom eww-suggest-uris
+  '(eww-links-at-point
+    url-get-url-at-point
+    eww-current-url)
+  "List of functions called to form the list of default URIs for `eww'.
+Each of the elements is a function returning either a string or a list
+of strings.  The results will be joined into a single list with
+duplicate entries (if any) removed."
+  :version "25.1"
+  :group 'eww
+  :type 'hook
+  :options '(eww-links-at-point
+	     url-get-url-at-point
+	     eww-current-url))
+
 (defcustom eww-bookmarks-directory user-emacs-directory
   "Directory where bookmark files will be stored."
   :version "25.1"
@@ -101,6 +123,7 @@
   :group 'eww
   :type '(choice (const :tag "Unlimited" nil)
                  integer))
+
 (defcustom eww-use-external-browser-for-content-type
   "\\`\\(video/\\|audio/\\|application/ogg\\)"
   "Always use external browser for specified content-type."
@@ -194,12 +218,31 @@
     (define-key map "\r" 'eww-follow-link)
     map))
 
+(defun eww-suggested-uris nil
+  "Return the list of URIs to suggest at the `eww' prompt.
+This list can be customized via `eww-suggest-uris'."
+  (let ((obseen (make-vector 42 0))
+	(uris nil))
+    (dolist (fun eww-suggest-uris)
+      (let ((ret (funcall fun)))
+	(dolist (uri (if (stringp ret) (list ret) ret))
+	  (when (and uri (not (intern-soft uri obseen)))
+	    (intern uri obseen)
+	    (push   uri uris)))))
+    ;; .
+    (nreverse uris)))
+
 ;;;###autoload
 (defun eww (url)
   "Fetch URL and render the page.
 If the input doesn't look like an URL or a domain name, the
 word(s) will be searched for via `eww-search-prefix'."
-  (interactive "sEnter URL or keywords: ")
+  (interactive
+   (let* ((uris (eww-suggested-uris))
+	  (prompt (concat "Enter URL or keywords"
+			  (if uris (format " (default %s)" (car uris) ""))
+			  ": ")))
+     (list (read-string prompt nil nil uris))))
   (setq url (string-trim url))
   (cond ((string-match-p "\\`file:/" url))
 	;; Don't mangle file: URLs at all.
@@ -454,6 +504,16 @@
   (unless (eq major-mode 'eww-mode)
     (eww-mode)))
 
+(defun eww-current-url nil
+  "Return URI of the Web page the current EWW buffer is visiting."
+  (plist-get eww-data :url))
+
+(defun eww-links-at-point (&optional pt)
+  "Return list of URIs, if any, linked at point."
+  (remq nil
+	(list (get-text-property (point) 'shr-url)
+	      (get-text-property (point) 'image-url))))
+
 (defun eww-view-source ()
   "View the HTML source code of the current page."
   (interactive)
@@ -548,6 +608,7 @@
     (suppress-keymap map)
     (define-key map "q" 'quit-window)
     (define-key map "g" 'eww-reload)
+    (define-key map "G" 'eww)
     (define-key map [?\t] 'shr-next-link)
     (define-key map [?\M-\t] 'shr-previous-link)
     (define-key map [delete] 'scroll-down-command)

Message #38 received at 19106 <at> debbugs.gnu.org (full text, mbox):

From: Lars Magne Ingebrigtsen <larsi <at> gnus.org>
To: Ivan Shmakov <ivan <at> siamics.net>
Cc: 19106 <at> debbugs.gnu.org
Subject: Re: bug#19106: M-x eww: provide default URIs; be bound to a key
Date: Sun, 23 Nov 2014 16:55:31 +0100

Ivan Shmakov <ivan <at> siamics.net> writes:

>>>>>> Ivan Shmakov <ivan <at> siamics.net> writes:
>
> 	Please consider the revised patch MIMEd.
>
> […]
>
>  > One may still wish to customize the order of the entries listed, or
>  > perhaps to add new ones (think of recognizing, say, RFC 7154 or
>  > RFC7154 as a link to http://tools.ietf.org/html/rfc7154, for
>  > instance), but to be convenient, there should probably be a couple of
>  > helper functions to correspond to the lambdas in the example code
>  > fragment also MIMEd.
>
> 	I’ve found that I myself prefer a different order for the
> 	default URIs than my previous patch suggested.  Therefore, I’ve
> 	ended up making it fully customizable.

Thanks; applied (with some changes due to compilation warnings).

-- 
(domestic pets only, the antidote for overdose, milk.)
   bloggy blog: http://lars.ingebrigtsen.no

Message #43 received at 19106-quiet <at> debbugs.gnu.org (full text, mbox):

From: Ivan Shmakov <ivan <at> siamics.net>
To: 19106-quiet <at> debbugs.gnu.org
Subject: Re: bug#19106: M-x eww: provide default URIs; be bound to a key 
Date: Tue, 25 Nov 2014 10:17:12 +0000

>>>>> Lars Magne Ingebrigtsen <larsi <at> gnus.org> writes:
>>>>> Ivan Shmakov <ivan <at> siamics.net> writes:

[…]

 >> I’ve found that I myself prefer a different order for the default
 >> URIs than my previous patch suggested.  Therefore, I’ve ended up
 >> making it fully customizable.

 > Thanks; applied (with some changes due to compilation warnings).

	I presume that means fixing a misplaced parenthesis on my part:

-			  (if uris (format " (default %s)" (car uris) ""))
+			  (if uris (format " (default %s)" (car uris)) "")

-- 
FSF associate member #7257  http://boycottsystemd.org/  … 3013 B6A0 230E 334A

Previous Next

GNU bug tracking system
Copyright (C) 1999 Darren O. Benham, 1997,2003 nCipher Corporation Ltd, 1994-97 Ian Jackson.