GNU bug report logs - #38344
[PATCH] gnu: Add qgo.

Previous Next

To add a comment to this bug, you must first unarchive it, by sending
a message to control AT debbugs.gnu.org, with unarchive 38344 in the body.
You can then email your comments to 38344 AT debbugs.gnu.org in the normal way.

Toggle the display of automated, internal messages from the tracker.

Message #5 received at submit <at> debbugs.gnu.org (full text, mbox):

From: Guillaume Le Vaillant <glv <at> posteo.net>
To: guix-patches <at> gnu.org
Cc: Guillaume Le Vaillant <glv <at> posteo.net>
Subject: [PATCH] gnu: Add qgo.
Date: Sat, 23 Nov 2019 13:56:54 +0100

* gnu/packages/games.scm (qgo): New variable.
---
 gnu/packages/games.scm | 71 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)

diff --git a/gnu/packages/games.scm b/gnu/packages/games.scm
index 3d825cbe61..e97af7609e 100644
--- a/gnu/packages/games.scm
+++ b/gnu/packages/games.scm
@@ -7809,3 +7809,74 @@ remake of that series or any other game.")
 the AlphaGo Zero paper.  The current best network weights file for the engine
 can be downloaded from @url{https://zero.sjeng.org/best-network}.")
    (license license:gpl3+)))
+
+(define-public qgo
+  (let ((commit "2a4212d473372bb531fdc5c919a20dd96819f9b0")
+        (revision "0"))
+    (package
+      (name "qgo")
+      (version (git-version "2.1.0" revision commit))
+      (source (origin
+                (method git-fetch)
+                (uri (git-reference
+                      (url "https://github.com/pzorin/qgo.git")
+                      (commit commit)))
+                (file-name (git-file-name name version))
+                (sha256
+                 (base32
+                  "0v03g0wp9vqzdn6ppxrhvabbz32ww83ipkk7178f8fqhm7ndvsbj"))))
+      (build-system gnu-build-system)
+      (native-inputs
+       `(("qttools" ,qttools)))
+      (inputs
+       `(("gnugo" ,gnugo)
+         ("qtbase" ,qtbase)
+         ("qtmultimedia" ,qtmultimedia)))
+      (arguments
+       `(#:modules ((guix build gnu-build-system)
+                    (guix build qt-utils)
+                    (guix build utils))
+         #:imported-modules (,@%gnu-build-system-modules
+                             (guix build qt-utils))
+         #:phases
+         (modify-phases %standard-phases
+           (add-after 'unpack 'fix-paths
+             (lambda* (#:key inputs outputs #:allow-other-keys)
+               (substitute* "src/src.pro"
+                 (("= /usr/")
+                  (string-append "= " (assoc-ref outputs "out") "/"))
+                 (("\\$\\$\\[QT_INSTALL_BINS\\]/lrelease")
+                  (string-append (assoc-ref inputs "qttools") "/bin/lrelease")))
+               (substitute* "src/defines.h"
+                 (("/usr/games/")
+                  (string-append (assoc-ref inputs "gnugo") "/bin/"))
+                 (("/usr/share/")
+                  (string-append (assoc-ref outputs "out") "/share/")))
+               (substitute* "src/main.cpp"
+                 (("QCoreApplication::applicationDirPath\\(\\)\\+\"")
+                  (string-append "\"" (assoc-ref outputs "out") "/share/qgo")))
+               #t))
+           (replace 'configure
+             (lambda _
+               (invoke "qmake" "src")))
+           (add-after 'install 'install-translations
+             (lambda* (#:key outputs #:allow-other-keys)
+               (let ((dest (string-append (assoc-ref outputs "out")
+                                          "/share/qgo/translations")))
+                 (for-each (lambda (file)
+                             (install-file file dest))
+                           (find-files "../source/src/translations/"
+                                       "qgo_.*\\.qm")))
+               #t))
+           (add-after 'install-translations 'wrap-program
+             (lambda* (#:key outputs #:allow-other-keys)
+               (let ((out (assoc-ref outputs "out")))
+                 (wrap-qt-program out "qgo"))
+               #t)))))
+      (synopsis "Qt GUI to play the game of Go")
+      (description
+       "This is a Go client.  It supports playing online at IGS-compatible
+servers and locally against GTP-compliant engines like @code{gnugo}.
+It also has rudimentary support for editing SGF files.")
+      (home-page "https://github.com/pzorin/qgo")
+      (license license:gpl2+))))
-- 
2.24.0

Message #8 received at 38344 <at> debbugs.gnu.org (full text, mbox):

From: Guillaume Le Vaillant <glv <at> posteo.net>
To: 38344 <at> debbugs.gnu.org
Cc: Guillaume Le Vaillant <glv <at> posteo.net>
Subject: Re: [PATCH] gnu: Add qgo.
Date: Sun, 24 Nov 2019 12:37:47 +0100

Guillaume Le Vaillant skribis:

> * gnu/packages/games.scm (qgo): New variable.
> ---
>  gnu/packages/games.scm | 71 ++++++++++++++++++++++++++++++++++++++++++
>  1 file changed, 71 insertions(+)

I found another fork of qGo called q5Go which might be better (more
features, more maintained). So let's not merge qGo right now. If
I succeed in getting q5Go packaged and working, I'll send a v2 patch for
q5Go to merge instead of the current qGo patch.

Message #11 received at 38344 <at> debbugs.gnu.org (full text, mbox):

From: Guillaume Le Vaillant <glv <at> posteo.net>
To: 38344 <at> debbugs.gnu.org
Cc: Guillaume Le Vaillant <glv <at> posteo.net>
Subject: [PATCH v2] gnu: Add q5go.
Date: Sun, 24 Nov 2019 16:17:09 +0100

* gnu/packages/games.scm (q5go): New variable.
---
 gnu/packages/games.scm | 81 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 81 insertions(+)

diff --git a/gnu/packages/games.scm b/gnu/packages/games.scm
index 3d825cbe61..b6004b639c 100644
--- a/gnu/packages/games.scm
+++ b/gnu/packages/games.scm
@@ -7809,3 +7809,84 @@ remake of that series or any other game.")
 the AlphaGo Zero paper.  The current best network weights file for the engine
 can be downloaded from @url{https://zero.sjeng.org/best-network}.")
    (license license:gpl3+)))
+
+(define-public q5go
+  (package
+   (name "q5go")
+   (version "1.0")
+   (source (origin
+            (method git-fetch)
+            (uri (git-reference
+                  (url "https://github.com/bernds/q5Go.git")
+                  (commit (string-append "q5go-" version))))
+            (file-name (git-file-name name version))
+            (sha256
+             (base32
+              "1gdlfqcqkqv7vph3qwq78d0qz6dhmdsranxq9bmixiisbzkqby31"))))
+   (build-system gnu-build-system)
+   (native-inputs
+    `(("pkg-config" ,pkg-config)))
+   (inputs
+    `(("qtbase" ,qtbase)
+      ("qtmultimedia" ,qtmultimedia)
+      ("qtsvg" ,qtsvg)))
+   (arguments
+    '(#:phases
+      (modify-phases %standard-phases
+        (add-after 'unpack 'fix-configure-script
+          (lambda _
+            ;; Bypass the unavailable qtchooser program.
+            (substitute* "configure"
+              (("test -z \"QTCHOOSER\"")
+               "false")
+              (("qtchooser -run-tool=(.*) -qt=qt5" _ command)
+               command))
+            #t))
+        (add-after 'unpack 'fix-paths
+          (lambda _
+            (substitute* '("src/pics/Makefile.in"
+                           "src/translations/Makefile.in")
+              (("\\$\\(datadir\\)/qGo/")
+               "$(datadir)/q5go/"))
+            #t))
+        (add-after 'install 'install-desktop-file
+          (lambda* (#:key outputs #:allow-other-keys)
+            (let* ((out (assoc-ref outputs "out"))
+                   (apps (string-append out "/share/applications"))
+                   (pics (string-append out "/share/q5go/pics")))
+              (delete-file-recursively (string-append out "/share/applnk"))
+              (delete-file-recursively (string-append out "/share/mimelnk"))
+              (install-file "../source/src/pics/Bowl.ico" pics)
+              (mkdir-p apps)
+              (with-output-to-file (string-append apps "/q5go.desktop")
+                (lambda _
+                  (format #t
+                          "[Desktop Entry]~@
+                           Name=q5go~@
+                           Exec=~a/bin/q5go~@
+                           Icon=~a/Bowl.ico~@
+                           Categories=Game;~@
+                           Comment=Game of Go~@
+                           Comment[de]=Spiel des Go~@
+                           Comment[eo]=Goo~@
+                           Comment[es]=Juego de Go~@
+                           Comment[fr]=Jeu de Go~@
+                           Comment[ja]=囲碁~@
+                           Comment[ko]=바둑~@
+                           Comment[zh]=围棋~@
+                           Terminal=false~@
+                           Type=Application~%"
+                          out pics))))
+             #t)))))
+   (synopsis "Qt GUI to play the game of Go")
+   (description
+    "This a tool for Go players which performs the following functions:
+@itemize
+@item SGF editor,
+@item Analysis frontend for Leela Zero (or compatible engines),
+@item GTP interface (to play against an engine),
+@item IGS client (to play on the internet),
+@item Export games to a variety of formats.
+@end itemize")
+   (home-page "https://github.com/bernds/q5Go")
+   (license license:gpl2+)))
-- 
2.24.0

Message #16 received at 38344-done <at> debbugs.gnu.org (full text, mbox):

From: Ludovic Courtès <ludo <at> gnu.org>
To: Guillaume Le Vaillant <glv <at> posteo.net>
Cc: 38344-done <at> debbugs.gnu.org
Subject: Re: [bug#38344] [PATCH v2] gnu: Add q5go.
Date: Mon, 02 Dec 2019 10:17:39 +0100

Hi,

Guillaume Le Vaillant <glv <at> posteo.net> skribis:

> * gnu/packages/games.scm (q5go): New variable.

Applied, thanks!

Ludo’.

Previous Next

GNU bug tracking system
Copyright (C) 1999 Darren O. Benham, 1997,2003 nCipher Corporation Ltd, 1994-97 Ian Jackson.