GNU bug report logs - #53953
[PATCH] gnu: Add acpilight.

Previous Next

To add a comment to this bug, you must first unarchive it, by sending
a message to control AT debbugs.gnu.org, with unarchive 53953 in the body.
You can then email your comments to 53953 AT debbugs.gnu.org in the normal way.

Toggle the display of automated, internal messages from the tracker.

Message #5 received at submit <at> debbugs.gnu.org (full text, mbox):

From: Brice Waegeneire <brice <at> waegenei.re>
To: guix-patches <at> gnu.org
Subject: [PATCH] gnu: Add acpilight.
Date: Sat, 12 Feb 2022 11:44:32 +0100

* gnu/packages/linux.scm (acpilight): New variable.
---
 gnu/packages/linux.scm | 42 +++++++++++++++++++++++++++++++++++++++++-
 1 file changed, 41 insertions(+), 1 deletion(-)

diff --git a/gnu/packages/linux.scm b/gnu/packages/linux.scm
index bcbaa2166d..2d6c024906 100644
--- a/gnu/packages/linux.scm
+++ b/gnu/packages/linux.scm
@@ -35,7 +35,7 @@
 ;;; Copyright © 2019 Tim Gesthuizen <tim.gesthuizen <at> yahoo.de>
 ;;; Copyright © 2019, 2020, 2021 Maxim Cournoyer <maxim.cournoyer <at> gmail.com>
 ;;; Copyright © 2019 Stefan Stefanović <stefanx2ovic <at> gmail.com>
-;;; Copyright © 2019, 2020, 2021 Brice Waegeneire <brice <at> waegenei.re>
+;;; Copyright © 2019-2022 Brice Waegeneire <brice <at> waegenei.re>
 ;;; Copyright © 2019 Kei Kebreau <kkebreau <at> posteo.net>
 ;;; Copyright © 2020, 2021 Oleg Pykhalov <go.wigust <at> gmail.com>
 ;;; Copyright © 2020 Pierre Neidhardt <mail <at> ambrevar.xyz>
@@ -8806,3 +8806,43 @@ (define-public libgpiod
     (license (list license:lgpl2.1+   ;; libgpiod
                    license:gpl2+      ;; gpio-tools
                    license:lgpl3+)))) ;; C++ bindings
+
+(define-public acpilight
+  (package
+    (name "acpilight")
+    (version "1.2")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://gitlab.com/wavexx/acpilight.git")
+                    (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "1r0r3nx6x6vkpal6vci0zaa1n9dfacypldf6k8fxg7919vzxdn1w"))))
+    (build-system gnu-build-system)
+    (arguments
+     `(#:tests? #f  ;no tests
+       #:make-flags (list "prefix="
+                          (string-append "DESTDIR="
+                                         (assoc-ref %outputs "out")))
+       #:phases
+       (modify-phases %standard-phases
+         (delete 'configure)
+         (add-after 'unpack 'patch
+           (lambda* (#:key inputs #:allow-other-keys)
+             (substitute* "Makefile"
+               (("udevadm") "true"))
+             (substitute* "90-backlight.rules"
+               (("/bin")
+                (string-append (assoc-ref inputs "coreutils") "/bin")))
+             #t)))))
+    (inputs
+     (list python))
+    (home-page "https://gitlab.com/wavexx/acpilight")
+    (synopsis "Backward-compatibile xbacklight replacement")
+    (description "acpilight is a backward-compatibile replacement for
+xbacklight that uses the ACPI interface to set the display
+brightness.  On modern laptops acpilight can control both display and
+keyboard backlight uniformly on either X11, the console or Wayland.")
+    (license license:gpl3+)))

base-commit: 068d99978a0c9c6fb66f95455060c8d08ba55ac5
-- 
2.34.0

Message #8 received at 53953 <at> debbugs.gnu.org (full text, mbox):

From: Maxime Devos <maximedevos <at> telenet.be>
To: Brice Waegeneire <brice <at> waegenei.re>, 53953 <at> debbugs.gnu.org
Subject: Re: [bug#53953] [PATCH] gnu: Add acpilight.
Date: Sat, 12 Feb 2022 14:34:02 +0100

[Message part 1 (text/plain, inline)]

Brice Waegeneire schreef op za 12-02-2022 om 11:44 [+0100]:
> +             (substitute* "90-backlight.rules"
> +               (("/bin")
> +                (string-append (assoc-ref inputs "coreutils") "/bin")))
> +             #t)))))
> +    (inputs
> +     (list python))

coreutils-minimal needs to be added to inputs, otherwise the
substitute* above won't work when cross-compiling.  Also, phases do not
have to return #t anymore.

Greetings,
Maxime

[signature.asc (application/pgp-signature, inline)]

Message #11 received at 53953 <at> debbugs.gnu.org (full text, mbox):

From: Maxime Devos <maximedevos <at> telenet.be>
To: Brice Waegeneire <brice <at> waegenei.re>, 53953 <at> debbugs.gnu.org
Subject: Re: [bug#53953] [PATCH] gnu: Add acpilight.
Date: Sat, 12 Feb 2022 14:38:39 +0100

[Message part 1 (text/plain, inline)]

Brice Waegeneire schreef op za 12-02-2022 om 11:44 [+0100]:
> +       #:make-flags (list "prefix="
> +                          (string-append "DESTDIR="
> +                                         (assoc-ref %outputs "out")))

%outputs, %build-inputs and friends are being deprecated (not 100%
sure, you might want to confirm with ludo) in favour of G-exps. More
concretely: (list #:make-flags #~(list "prefix=" (string-append
"DESTDIR=" #$output))).

Also, about prefix= and DESTDIR=, it's normally the other way around.

#~(list ; (probably) no need to set DESTDIR=, it's normally "" by default:
        (string-append "prefix=" #$output)).

(Search for "Staged installation" for details)

Also, are you sure about the case of 'prefix'?  Usually, Makefiles use
uppercase 'PREFIX' and not 'prefix' (for ./configure, it's other way
around).

Greetings,
Maxime.

[signature.asc (application/pgp-signature, inline)]

Message #14 received at 53953 <at> debbugs.gnu.org (full text, mbox):

From: Brice Waegeneire <brice <at> waegenei.re>
To: maximedevos <at> telenet.be
Cc: 53953 <at> debbugs.gnu.org
Subject: [PATCH v2] gnu: Add acpilight.
Date: Sat, 12 Feb 2022 18:21:25 +0100

* gnu/packages/linux.scm (acpilight): New variable.
---
Maxime,

Thanks for the review.  I should have re-read this old package more throughly,
I have fixed what you pointed out:
- using gexp in arguments field
- don't returning #t in phases
- adding coreutils-minimal to inputs

As for the odd make-flags, this is because of the uncanonical Makefile¹ of
acpilight, It don't build with an empty DESTDIR.

¹ https://gitlab.com/wavexx/acpilight/-/blob/master/Makefile

Cheers,
- Brice

 gnu/packages/linux.scm | 40 +++++++++++++++++++++++++++++++++++++++-
 1 file changed, 39 insertions(+), 1 deletion(-)

diff --git a/gnu/packages/linux.scm b/gnu/packages/linux.scm
index bcbaa2166d..fe88d9ad26 100644
--- a/gnu/packages/linux.scm
+++ b/gnu/packages/linux.scm
@@ -35,7 +35,7 @@
 ;;; Copyright © 2019 Tim Gesthuizen <tim.gesthuizen <at> yahoo.de>
 ;;; Copyright © 2019, 2020, 2021 Maxim Cournoyer <maxim.cournoyer <at> gmail.com>
 ;;; Copyright © 2019 Stefan Stefanović <stefanx2ovic <at> gmail.com>
-;;; Copyright © 2019, 2020, 2021 Brice Waegeneire <brice <at> waegenei.re>
+;;; Copyright © 2019-2022 Brice Waegeneire <brice <at> waegenei.re>
 ;;; Copyright © 2019 Kei Kebreau <kkebreau <at> posteo.net>
 ;;; Copyright © 2020, 2021 Oleg Pykhalov <go.wigust <at> gmail.com>
 ;;; Copyright © 2020 Pierre Neidhardt <mail <at> ambrevar.xyz>
@@ -8806,3 +8806,41 @@ (define-public libgpiod
     (license (list license:lgpl2.1+   ;; libgpiod
                    license:gpl2+      ;; gpio-tools
                    license:lgpl3+)))) ;; C++ bindings
+
+(define-public acpilight
+  (package
+    (name "acpilight")
+    (version "1.2")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://gitlab.com/wavexx/acpilight.git")
+                    (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "1r0r3nx6x6vkpal6vci0zaa1n9dfacypldf6k8fxg7919vzxdn1w"))))
+    (build-system gnu-build-system)
+    (arguments
+     (list #:tests? #f  ;no tests
+           #:make-flags #~(list "prefix="
+                                (string-append "DESTDIR=" #$output))
+           #:phases
+           #~(modify-phases %standard-phases
+               (delete 'configure)
+               (add-after 'unpack 'patch
+                 (lambda* (#:key inputs #:allow-other-keys)
+                   (substitute* "Makefile"
+                     (("udevadm") "true"))
+                   (substitute* "90-backlight.rules"
+                     (("/bin")
+                      (string-append (assoc-ref inputs "coreutils-minimal") "/bin"))))))))
+    (inputs
+     (list python coreutils-minimal))
+    (home-page "https://gitlab.com/wavexx/acpilight")
+    (synopsis "Backward-compatibile xbacklight replacement")
+    (description "acpilight is a backward-compatibile replacement for
+xbacklight that uses the ACPI interface to set the display
+brightness.  On modern laptops acpilight can control both display and
+keyboard backlight uniformly on either X11, the console or Wayland.")
+    (license license:gpl3+)))

base-commit: e641d707e1ec8de2bfc658dcd1757360300aa509
-- 
2.34.0

Message #17 received at 53953 <at> debbugs.gnu.org (full text, mbox):

From: Maxime Devos <maximedevos <at> telenet.be>
To: Brice Waegeneire <brice <at> waegenei.re>
Cc: 53953 <at> debbugs.gnu.org
Subject: Re: [PATCH v2] gnu: Add acpilight.
Date: Sat, 12 Feb 2022 19:05:24 +0100

[Message part 1 (text/plain, inline)]

Brice Waegeneire schreef op za 12-02-2022 om 18:21 [+0100]:
> As for the odd make-flags, this is because of the uncanonical Makefile¹ of
> acpilight, It don't build with an empty DESTDIR.
> 
> ¹ https://gitlab.com/wavexx/acpilight/-/blob/master/Makefile

Looks like the problem is caused by 'sysconfdir' not being based
on 'prefix', but that can be resolved by

#~(list (string-append "prefix=" #$output)
	(string-append "sysconfdir=" (string-append #$output "/etc")))

which is not 100% canonical, but it does seems closer to me?

Also, apparently there's a 'python-minimal' package, so you could use
that instead of 'python' to reduce the closure?  Might be counter-
productive though, since most packages seem to use plain 'python'
instead ...

whose closure
would be smaller than

[signature.asc (application/pgp-signature, inline)]

Message #20 received at 53953 <at> debbugs.gnu.org (full text, mbox):

From: Brice Waegeneire <brice <at> waegenei.re>
To: maximedevos <at> telenet.be
Cc: 53953 <at> debbugs.gnu.org
Subject: [PATCH v3] gnu: Add acpilight.
Date: Wed, 16 Feb 2022 08:22:32 +0100

* gnu/packages/linux.scm (acpilight): New variable.
---
Hello Maxime,

Maxime Devos <maximedevos <at> telenet.be> writes:

> Brice Waegeneire schreef op za 12-02-2022 om 18:21 [+0100]:
>> As for the odd make-flags, this is because of the uncanonical Makefile¹ of
>> acpilight, It don't build with an empty DESTDIR.
>> 
>> ¹ https://gitlab.com/wavexx/acpilight/-/blob/master/Makefile
>
> Looks like the problem is caused by 'sysconfdir' not being based
> on 'prefix', but that can be resolved by
>
> #~(list (string-append "prefix=" #$output)
> 	(string-append "sysconfdir=" (string-append #$output "/etc")))
>
> which is not 100% canonical, but it does seems closer to me?

I remember trying someting like that unsuccesfully before sending the previous
patch version but I probablly missend something because it actually work!

> Also, apparently there's a 'python-minimal' package, so you could use
> that instead of 'python' to reduce the closure?  Might be counter-
> productive though, since most packages seem to use plain 'python'
> instead ...

Done.

Cheers,
- Brice

 gnu/packages/linux.scm | 44 +++++++++++++++++++++++++++++++++++++++++-
 1 file changed, 43 insertions(+), 1 deletion(-)

diff --git a/gnu/packages/linux.scm b/gnu/packages/linux.scm
index 4edb5bf858..fd68901391 100644
--- a/gnu/packages/linux.scm
+++ b/gnu/packages/linux.scm
@@ -35,7 +35,7 @@
 ;;; Copyright © 2019 Tim Gesthuizen <tim.gesthuizen <at> yahoo.de>
 ;;; Copyright © 2019, 2020, 2021 Maxim Cournoyer <maxim.cournoyer <at> gmail.com>
 ;;; Copyright © 2019 Stefan Stefanović <stefanx2ovic <at> gmail.com>
-;;; Copyright © 2019, 2020, 2021 Brice Waegeneire <brice <at> waegenei.re>
+;;; Copyright © 2019-2022 Brice Waegeneire <brice <at> waegenei.re>
 ;;; Copyright © 2019 Kei Kebreau <kkebreau <at> posteo.net>
 ;;; Copyright © 2020, 2021 Oleg Pykhalov <go.wigust <at> gmail.com>
 ;;; Copyright © 2020 Pierre Neidhardt <mail <at> ambrevar.xyz>
@@ -8806,3 +8806,45 @@ (define-public libgpiod
     (license (list license:lgpl2.1+   ;; libgpiod
                    license:gpl2+      ;; gpio-tools
                    license:lgpl3+)))) ;; C++ bindings
+
+(define-public acpilight
+  (package
+    (name "acpilight")
+    (version "1.2")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://gitlab.com/wavexx/acpilight.git")
+                    (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "1r0r3nx6x6vkpal6vci0zaa1n9dfacypldf6k8fxg7919vzxdn1w"))))
+    (build-system gnu-build-system)
+    (arguments
+     (list #:tests? #f                  ; no tests
+           #:make-flags
+           #~(list (string-append "prefix=" #$output)
+                   (string-append "sysconfdir=" #$output "/etc"))
+           #:phases
+           #~(modify-phases %standard-phases
+               (delete 'configure)
+               (add-after 'unpack 'patch
+                 (lambda* (#:key inputs #:allow-other-keys)
+                   ;; Prevent reloading udev at build time
+                   (substitute* "Makefile"
+                     (("udevadm") "true"))
+                   (substitute* "90-backlight.rules"
+                     (("/bin")
+                      (string-append (assoc-ref inputs "coreutils-minimal")
+                                     "/bin"))))))))
+    (inputs
+     (list coreutils-minimal
+           python-minimal))
+    (home-page "https://gitlab.com/wavexx/acpilight")
+    (synopsis "Backward-compatibile xbacklight replacement")
+    (description "acpilight is a backward-compatibile replacement for
+xbacklight that uses the ACPI interface to set the display
+brightness.  On modern laptops acpilight can control both display and
+keyboard backlight uniformly on either X11, the console or Wayland.")
+    (license license:gpl3+)))

base-commit: 52269e27c628d34af896e95347870b1755cb3e5f
-- 
2.34.0

Message #23 received at 53953 <at> debbugs.gnu.org (full text, mbox):

From: Ludovic Courtès <ludo <at> gnu.org>
To: Brice Waegeneire <brice <at> waegenei.re>
Cc: 53953 <at> debbugs.gnu.org, maximedevos <at> telenet.be
Subject: Re: bug#53953: [PATCH] gnu: Add acpilight.
Date: Sun, 06 Mar 2022 22:17:57 +0100

Hi Brice,

Brice Waegeneire <brice <at> waegenei.re> skribis:

> * gnu/packages/linux.scm (acpilight): New variable.

LGTM, please push!

Thanks,
Ludo’.

Message #26 received at 53953 <at> debbugs.gnu.org (full text, mbox):

From: Ludovic Courtès <ludo <at> gnu.org>
To: Brice Waegeneire <brice <at> waegenei.re>
Cc: 53953 <at> debbugs.gnu.org, maximedevos <at> telenet.be
Subject: Re: bug#53953: [PATCH] gnu: Add acpilight.
Date: Tue, 05 Apr 2022 18:06:51 +0200

Ping! :-)

Ludovic Courtès <ludo <at> gnu.org> skribis:

> Hi Brice,
>
> Brice Waegeneire <brice <at> waegenei.re> skribis:
>
>> * gnu/packages/linux.scm (acpilight): New variable.
>
> LGTM, please push!
>
> Thanks,
> Ludo’.

Message #29 received at 53953 <at> debbugs.gnu.org (full text, mbox):

From: Antero Mejr <antero <at> mailbox.org>
To: "53953 <at> debbugs.gnu.org" <53953 <at> debbugs.gnu.org>
Subject: Re: bug#53953: [PATCH] gnu: Add acpilight.
Date: Wed, 1 Jun 2022 10:14:11 -0400 (EDT)

Any update on this merge? I was hoping to install acpilight but it doesn't appear to be in the latest master (commit 16a0aea02d). Thanks.

Message #34 received at 53953-done <at> debbugs.gnu.org (full text, mbox):

From: Maxim Cournoyer <maxim.cournoyer <at> gmail.com>
To: Ludovic Courtès <ludo <at> gnu.org>
Cc: maximedevos <at> telenet.be, 53953-done <at> debbugs.gnu.org,
 Brice Waegeneire <brice <at> waegenei.re>
Subject: Re: bug#53953: [PATCH] gnu: Add acpilight.
Date: Wed, 28 Sep 2022 15:57:24 -0400

Hello,

Ludovic Courtès <ludo <at> gnu.org> writes:

> Ping! :-)
>
> Ludovic Courtès <ludo <at> gnu.org> skribis:
>
>> Hi Brice,
>>
>> Brice Waegeneire <brice <at> waegenei.re> skribis:
>>
>>> * gnu/packages/linux.scm (acpilight): New variable.
>>
>> LGTM, please push!

Pushed myself, closing!

Maxim

Previous Next

GNU bug tracking system
Copyright (C) 1999 Darren O. Benham, 1997,2003 nCipher Corporation Ltd, 1994-97 Ian Jackson.