GNU bug report logs - #75934
[PATCH] services: networking: Add dhcpcd service.

Previous Next

To reply to this bug, email your comments to 75934 AT debbugs.gnu.org.
There is no need to reopen the bug first.

Toggle the display of automated, internal messages from the tracker.

Message #5 received at submit <at> debbugs.gnu.org (full text, mbox):

From: soeren <at> soeren-tempel.net
To: guix-patches <at> gnu.org
Cc: Quelln <at> protonmail.com, ludo <at> gnu.org
Subject: [PATCH] services: networking: Add dhcpcd service.
Date: Wed, 29 Jan 2025 21:45:22 +0100

From: Sören Tempel <soeren <at> soeren-tempel.net>

This is intended as an alternative to dhcp-client-service-type as
isc-dhcp has reached its end-of-life in 2022 (three years ago!),
see #68619 for more details.  Long-term, this services is therefore
intended to replace dhcp-client-service-type.

* gnu/services/networking.scm (dhcpcd-service-type): New service.
(dhcpcd-shepherd-service): New procedure.
(dhcpcd-account-service): New variable.
(dhcpcd-config-file): New procedure.
(dhcpcd-configuration): New record type.
(dhcpcd-serialize-list-of-strings, dhcpcd-serialize-boolean)
(dhcpcd-serialize-string): New procedures.
* gnu/tests/networking.scm (run-dhcpcd-test): New procedure.
(%dhcpcd-os, %test-dhcpcd): New variables.
* doc/guix.texi (Networking Services): Document it.
---
Previously, an integration into the dhcp-client-service-type was
attempted.  However, the discussion there established that a new
entirely separate service would be a better fit.

See https://issues.guix.gnu.org/68675 for the prior discussion.

 doc/guix.texi               |  57 ++++++++++++++
 gnu/services/networking.scm | 147 ++++++++++++++++++++++++++++++++++++
 gnu/tests/networking.scm    | 106 ++++++++++++++++++++++++++
 3 files changed, 310 insertions(+)

diff --git a/doc/guix.texi b/doc/guix.texi
index b1b6d98e74..6f51d1e1f6 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -21468,6 +21468,63 @@ which provides the @code{networking} Shepherd service.
 @end table
 @end deftp
 
+@cindex DHCPCD, networking service
+
+@defvar dhcpcd-service-type
+This is a service which runs @var{dhcpcd}, an alternative Dynamic
+Host Configuration Protocol (DHCP) client.
+@end defvar
+
+@deftp {Data Type} dhcpcd-configuration
+Available @code{dhcpcd-configuration} fields are:
+
+@table @asis
+@item @code{interfaces} (default: @code{()}) (type: list)
+List of interfaces to start a DHCP client for.
+
+@item @code{command-args} (default: @code{("-q" "-q")}) (type: list)
+List of additional command-line options.
+
+@item @code{hostname} (default: @code{""}) (type: maybe-string)
+Hostname to send via DHCP, defaults to the current system hostname.
+
+@item @code{duid} (default: @code{""}) (type: maybe-string)
+Use and generate a DHCP Unique Identifier.
+
+@item @code{persistent} (default: @code{#t}) (type: boolean)
+Do not de-configure on shutdown.
+
+@item @code{option} (default: @code{("rapid_commit" "domain_name_servers" "domain_name" "domain_search" "host_name" "classless_static_routes" "interface_mtu")}) (type: list-of-strings)
+List of options to request from the server.
+
+@item @code{require} (default: @code{("dhcp_server_identifier")}) (type: list-of-strings)
+List of options to require in responses.
+
+@item @code{slaac} (default: @code{"private"}) (type: maybe-string)
+Interface identifier used for SLAAC generated IPv6 addresses.
+
+@item @code{nooption} (default: @code{()}) (type: list-of-strings)
+List of options to remove from the message before it's processed.
+
+@item @code{nohook} (default: @code{()}) (type: list-of-strings)
+List of hook script which should not be invoked.
+
+@item @code{static} (default: @code{()}) (type: list-of-strings)
+Configure a static value (e.g.  ip_address).
+
+@item @code{vendorclassid} (type: maybe-string)
+Set the DHCP Vendor Class.
+
+@item @code{clientid} (type: maybe-string)
+Use the interface hardware address or the given string as a Client ID.
+
+@item @code{extra-content} (type: maybe-string)
+Extra content to append to the configuration as-is.
+
+@end table
+@end deftp
+
+
 @cindex NetworkManager
 
 @defvar network-manager-service-type
diff --git a/gnu/services/networking.scm b/gnu/services/networking.scm
index af28bd0626..c97d50eccf 100644
--- a/gnu/services/networking.scm
+++ b/gnu/services/networking.scm
@@ -108,6 +108,24 @@ (define-module (gnu services networking)
             dhcpd-configuration-pid-file
             dhcpd-configuration-interfaces
 
+            dhcpcd-service-type
+            dhcpcd-configuration
+            dhcpcd-configuration?
+            dhcpcd-configuration-interfaces
+            dhcpcd-configuration-command-args
+            dhcpcd-configuration-hostname
+            dhcpcd-configuration-duid
+            dhcpcd-configuration-persistent
+            dhcpcd-configuration-option
+            dhcpcd-configuration-require
+            dhcpcd-configuration-slaac
+            dhcpcd-configuration-nooption
+            dhcpcd-configuration-nohook
+            dhcpcd-configuration-static
+            dhcpcd-configuration-vendorclassid
+            dhcpcd-configuration-clientid
+            dhcpcd-configuration-extra-content
+
             ntp-configuration
             ntp-configuration?
             ntp-configuration-ntp
@@ -491,6 +509,135 @@ (define dhcpd-service-type
    (description "Run a DHCP (Dynamic Host Configuration Protocol) daemon.  The
 daemon is responsible for allocating IP addresses to its client.")))
 
+
+;;
+;; DHCPCD.
+;;
+
+(define (dhcpcd-serialize-string field-name value)
+  (let ((field (object->string field-name)))
+    (if (string=? field "extra-content")
+      #~(string-append #$value "\n")
+      #~(format #f "~a ~a~%" #$field #$value))))
+
+(define (dhcpcd-serialize-boolean field-name value)
+  (if value
+    #~(format #f "~a~%" #$(object->string field-name))
+    ""))
+
+(define (dhcpcd-serialize-list-of-strings field-name value)
+  #~(string-append #$@(map (cut dhcpcd-serialize-string field-name <>) value)))
+
+;; Some fields (e.g. hostname) can be specified with an empty string argument.
+;; Therefore, we need a maybe type to differentiate disabled/empty-string.
+(define-maybe string (prefix dhcpcd-))
+
+(define-configuration dhcpcd-configuration
+  (interfaces
+    (list '())
+    "List of interfaces to start a DHCP client for."
+    empty-serializer)
+  (command-args
+    (list '("-q" "-q"))
+    "List of additional command-line options."
+    empty-serializer)
+
+  ;; The following defaults replicate the default dhcpcd configuration file.
+  ;;
+  ;; See https://github.com/NetworkConfiguration/dhcpcd/tree/v10.0.10#configuration
+  (hostname
+    (maybe-string "")
+    "Hostname to send via DHCP, defaults to the current system hostname.")
+  (duid
+    (maybe-string "")
+    "Use and generate a DHCP Unique Identifier.")
+  (persistent
+    (boolean #t)
+    "Do not de-configure on shutdown.")
+  (option
+    (list-of-strings
+      '("rapid_commit"
+        "domain_name_servers"
+        "domain_name"
+        "domain_search"
+        "host_name"
+        "classless_static_routes"
+        "interface_mtu"))
+    "List of options to request from the server.")
+  (require
+    (list-of-strings '("dhcp_server_identifier"))
+    "List of options to require in responses.")
+  (slaac
+    (maybe-string "private")
+    "Interface identifier used for SLAAC generated IPv6 addresses.")
+
+  ;; Common options not set in the default configuration file.
+  (nooption
+    (list-of-strings '())
+    "List of options to remove from the message before it's processed.")
+  (nohook
+    (list-of-strings '())
+    "List of hook script which should not be invoked.")
+  (static
+    (list-of-strings '())
+    "Configure a static value (e.g. ip_address).")
+  (vendorclassid
+    maybe-string
+    "Set the DHCP Vendor Class.")
+  (clientid
+    maybe-string
+    "Use the interface hardware address or the given string as a Client ID.")
+
+  ;; Escape hatch for the generated configuration file.
+  (extra-content
+    maybe-string
+    "Extra content to append to the configuration as-is.")
+
+  (prefix dhcpcd-))
+
+(define (dhcpcd-config-file config)
+  (mixed-text-file "dhcpcd.conf"
+    (serialize-configuration
+      config
+      dhcpcd-configuration-fields)))
+
+(define dhcpcd-account-service
+  (list (user-group (name "dhcpcd") (system? #t))
+        (user-account
+          (name "dhcpcd")
+          (group "dhcpcd")
+          (system? #t)
+          (comment "dhcpcd daemon user")
+          (home-directory "/var/empty")
+          (shell (file-append shadow "/sbin/nologin")))))
+
+(define (dhcpcd-shepherd-service config)
+  (let* ((config-file (dhcpcd-config-file config))
+         (command-args (dhcpcd-configuration-command-args config))
+         (ifaces (dhcpcd-configuration-interfaces config)))
+    (list (shepherd-service
+            (documentation "dhcpcd daemon.")
+            (provision '(networking))
+            (requirement '(user-processes udev))
+            (actions (list (shepherd-configuration-action config-file)))
+            (start
+              #~(lambda _
+                  (fork+exec-command
+                    (list (string-append #$dhcpcd "/sbin/dhcpcd")
+                          #$@command-args "-B" "-f" #$config-file #$@ifaces))))
+            (stop #~(make-kill-destructor))))))
+
+(define dhcpcd-service-type
+  (service-type (name 'dhcpcd)
+                (description "Run the dhcpcd daemon.")
+                (extensions
+                 (list (service-extension account-service-type
+                                          (const dhcpcd-account-service))
+                       (service-extension shepherd-root-service-type
+                                          dhcpcd-shepherd-service)))
+                (compose concatenate)
+                (default-value (dhcpcd-configuration))))
+
 
 ;;;
 ;;; NTP.
diff --git a/gnu/tests/networking.scm b/gnu/tests/networking.scm
index e7c02b9e00..720f123953 100644
--- a/gnu/tests/networking.scm
+++ b/gnu/tests/networking.scm
@@ -32,6 +32,7 @@ (define-module (gnu tests networking)
   #:use-module (guix store)
   #:use-module (guix monads)
   #:use-module (guix modules)
+  #:use-module (gnu packages admin)
   #:use-module (gnu packages bash)
   #:use-module (gnu packages linux)
   #:use-module (gnu packages networking)
@@ -44,6 +45,7 @@ (define-module (gnu tests networking)
             %test-inetd
             %test-openvswitch
             %test-dhcpd
+            %test-dhcpcd
             %test-tor
             %test-iptables
             %test-ipfs))
@@ -673,6 +675,110 @@ (define %test-dhcpd
    (description "Test a running DHCP daemon configuration.")
    (value (run-dhcpd-test))))
 
+
+;;;
+;;; DHCPCD Daemon
+;;;
+
+(define %dhcpcd-os
+  (let ((base-os
+          (simple-operating-system
+            (service dhcpcd-service-type
+                     (dhcpcd-configuration
+                       (command-args '("--debug" "--logfile" "/dev/console"))
+                       (interfaces '("ens3")))))))
+    (operating-system
+      (inherit base-os)
+      (packages
+        (append (list dhcpcd iproute)
+                (operating-system-packages base-os))))))
+
+(define (run-dhcpcd-test)
+  "Run tests in %dhcpcd-os with a running dhcpcd daemon on localhost."
+  (define os
+    (marionette-operating-system
+     %dhcpcd-os
+     #:imported-modules '((gnu services herd))))
+
+  (define vm
+    (virtual-machine os))
+
+  (define test
+    (with-imported-modules '((gnu build marionette))
+      #~(begin
+          (use-modules (srfi srfi-64)
+                       (gnu build marionette))
+          (define marionette
+            (make-marionette (list #$vm)))
+
+          (define (wait-for-lease)
+            (marionette-eval
+              '(begin
+                 (use-modules (ice-9 popen) (ice-9 rdelim))
+
+                 (let loop ((i 15))
+                   (if (> i 0)
+                     (let* ((port (open-input-pipe "dhcpcd --dumplease ens3"))
+                            (output (read-string port)))
+                       (close-port port)
+                       (unless (string-contains output "reason=BOUND")
+                         (sleep 1)
+                         (loop (- i 1))))
+                     (error "failed to obtain a DHCP lease"))))
+              marionette))
+
+          (test-runner-current (system-test-runner #$output))
+          (test-begin "dhcpcd")
+
+          (test-assert "service is running"
+            (marionette-eval
+             '(begin
+                (use-modules (gnu services herd))
+
+                ;; Make sure the 'dhcpcd' command is found.
+                (setenv "PATH" "/run/current-system/profile/sbin")
+
+                (wait-for-service 'networking))
+             marionette))
+
+          (test-assert "IPC socket exists"
+            (marionette-eval
+              '(file-exists? "/var/run/dhcpcd/ens3.sock")
+              marionette))
+
+          (test-equal "IPC is functional"
+            0
+            (marionette-eval
+              '(status:exit-val
+                 (system* "dhcpcd" "--dumplease" "ens3"))
+              marionette))
+
+          (test-equal "aquires IPv4 address via DHCP"
+            1
+            (and
+              (wait-for-lease)
+              (marionette-eval
+                '(begin
+                   (use-modules (ice-9 popen) (ice-9 rdelim))
+
+                   (let* ((port  (open-input-pipe "ip -4 address show dev ens3"))
+                          (lines (string-split (read-string port) #\newline)))
+                     (close-port port)
+                     (length
+                       (filter (lambda (line)
+                                 (string-contains line "scope global dynamic"))
+                               lines))))
+                marionette)))
+
+          (test-end))))
+  (gexp->derivation "dhcpcd-test" test))
+
+(define %test-dhcpcd
+  (system-test
+   (name "dhcpcd")
+   (description "Test that the dhcpcd obtains IP DHCP leases.")
+   (value (run-dhcpcd-test))))
+
 
 ;;;
 ;;; Services related to Tor

Message #8 received at 75934 <at> debbugs.gnu.org (full text, mbox):

From: Ludovic Courtès <ludo <at> gnu.org>
To: soeren <at> soeren-tempel.net
Cc: Quelln <at> protonmail.com, 873216071 <at> qq.com, 75934 <at> debbugs.gnu.org
Subject: Re: [bug#75934] [PATCH] services: networking: Add dhcpcd service.
Date: Wed, 05 Mar 2025 19:29:00 +0100

Hi,

soeren <at> soeren-tempel.net skribis:

> From: Sören Tempel <soeren <at> soeren-tempel.net>
>
> This is intended as an alternative to dhcp-client-service-type as
> isc-dhcp has reached its end-of-life in 2022 (three years ago!),
> see #68619 for more details.  Long-term, this services is therefore
> intended to replace dhcp-client-service-type.
>
> * gnu/services/networking.scm (dhcpcd-service-type): New service.
> (dhcpcd-shepherd-service): New procedure.
> (dhcpcd-account-service): New variable.
> (dhcpcd-config-file): New procedure.
> (dhcpcd-configuration): New record type.
> (dhcpcd-serialize-list-of-strings, dhcpcd-serialize-boolean)
> (dhcpcd-serialize-string): New procedures.
> * gnu/tests/networking.scm (run-dhcpcd-test): New procedure.
> (%dhcpcd-os, %test-dhcpcd): New variables.
> * doc/guix.texi (Networking Services): Document it.
> ---
> Previously, an integration into the dhcp-client-service-type was
> attempted.  However, the discussion there established that a new
> entirely separate service would be a better fit.
>
> See https://issues.guix.gnu.org/68675 for the prior discussion.

Nice, thanks for working on it.

Overall LGTM.  Some rather minor suggestions below:

> +@cindex DHCPCD, networking service
> +
> +@defvar dhcpcd-service-type
> +This is a service which runs @var{dhcpcd}, an alternative Dynamic
> +Host Configuration Protocol (DHCP) client.
> +@end defvar

What about something like this, to provide more context:

  This the type for a service running @command{dhcpcd}, a @acronym{DHCP,
  Dynamic Host Configuration Protocol} client that can be used as a
  replacement for the historical ISC client supported by
  @code{dhcp-client-service-type}.

  Its value must be a @code{dhcpcd-configuration} record, as described
  below.

> +(define (dhcpcd-serialize-string field-name value)
> +  (let ((field (object->string field-name)))
> +    (if (string=? field "extra-content")
> +      #~(string-append #$value "\n")
> +      #~(format #f "~a ~a~%" #$field #$value))))

Please indent ‘if’ expressions like this:

  (if condition
      then
      else)

> +(define-configuration dhcpcd-configuration
> +  (interfaces
> +    (list '())
> +    "List of interfaces to start a DHCP client for."

“List of networking interfaces---e.g., @code{\"eth0\"}---to start …”

Perhaps also explain what happens when it’s the empty list.

> +  (command-args

s/command-args/command-arguments/

> +    (list '("-q" "-q"))

Twice?

> +  (hostname
> +    (maybe-string "")
> +    "Hostname to send via DHCP, defaults to the current system hostname.")

Rather ‘host-name’ and “Host name”.  :-)

> +  (duid
> +    (maybe-string "")
> +    "Use and generate a DHCP Unique Identifier.")

This isn’t clear to me; make sure to describe what the value represents.

> +  (persistent
> +    (boolean #t)
> +    "Do not de-configure on shutdown.")

Rather ‘persistent?’ (question mark), and perhaps something like:

  “When true, preserve configuration on disk when shutting down and
  reuse it when restarting.”

> +  ;; Common options not set in the default configuration file.
> +  (nooption
> +    (list-of-strings '())
> +    "List of options to remove from the message before it's processed.")
> +  (nohook
> +    (list-of-strings '())
> +    "List of hook script which should not be invoked.")

‘excluded-options’, ‘excluded-hooks’ maybe?

> +  (static
> +    (list-of-strings '())
> +    "Configure a static value (e.g. ip_address).")

‘static-values’?  An example would be welcome.

> +  (vendorclassid
> +    maybe-string
> +    "Set the DHCP Vendor Class.")
> +  (clientid
> +    maybe-string
> +    "Use the interface hardware address or the given string as a Client ID.")

‘vendor-class-id’, ‘client-id’, but again with examples probably.

> +            (actions (list (shepherd-configuration-action config-file)))
> +            (start
> +              #~(lambda _
> +                  (fork+exec-command
> +                    (list (string-append #$dhcpcd "/sbin/dhcpcd")
> +                          #$@command-args "-B" "-f" #$config-file #$@ifaces))))

Rather:

  (start #~(make-forkexec-constructor (list …)))

The system test is pretty nice!

Could you send an updated version?

Thanks,
Ludo’.

Message #11 received at 75934 <at> debbugs.gnu.org (full text, mbox):

From: soeren <at> soeren-tempel.net
To: 75934 <at> debbugs.gnu.org
Cc: ludo <at> gnu.org
Subject: [PATCH v2] services: networking: Add dhcpcd service.
Date: Fri,  7 Mar 2025 15:29:05 +0100

From: Sören Tempel <soeren <at> soeren-tempel.net>

This is intended as an alternative to dhcp-client-service-type as
isc-dhcp has reached its end-of-life in 2022 (three years ago!),
see #68619 for more details.  Long-term, this services is therefore
intended to replace dhcp-client-service-type.

* gnu/services/networking.scm (dhcpcd-service-type): New service.
(dhcpcd-shepherd-service): New procedure.
(dhcpcd-account-service): New variable.
(dhcpcd-config-file): New procedure.
(dhcpcd-configuration): New record type.
(dhcpcd-serialize-list-of-strings, dhcpcd-serialize-boolean)
(dhcpcd-serialize-string): New procedures.
(serialize-field-name): New procedure.
* gnu/tests/networking.scm (run-dhcpcd-test): New procedure.
(%dhcpcd-os, %test-dhcpcd): New variables.
* doc/guix.texi (Networking Services): Document it.
---
Change since v1:

* Expand documentation and include a larger configuration example
* Improve record type by hyphening record field names
* Use make-forkexec-constructor in shepherd service
* Fix indention of if expression

 doc/guix.texi               |  89 ++++++++++++++++++++
 gnu/services/networking.scm | 161 ++++++++++++++++++++++++++++++++++++
 gnu/tests/networking.scm    | 106 ++++++++++++++++++++++++
 3 files changed, 356 insertions(+)

diff --git a/doc/guix.texi b/doc/guix.texi
index 6844470ce2..6529865c09 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -21594,6 +21594,95 @@ Networking Setup
 @end table
 @end deftp
 
+@cindex DHCPCD, networking service
+
+@defvar dhcpcd-service-type
+This the type for a service running @command{dhcpcd}, a @acronym{DHCP,
+Dynamic Host Configuration Protocol} client that can be used as a
+replacement for the historical ISC client supported by
+@code{dhcp-client-service-type}.
+
+Its value must be a @code{dhcpcd-configuration} record, as described
+below.  As an example, consider the following setup which runs
+@command{dhcpcd} with a local @acronym{DNS, Domain Name System}
+resolver:
+
+@lisp
+(service dhcpcd-service-type
+  (dhcpcd-configuration
+    (option '("rapid_commit" "interface_mtu"))
+    (no-option '("nd_rdnss"
+                 "dhcp6_name_servers"
+                 "domain_name_servers"
+                 "domain_name"
+                 "domain_search"))
+    (static '("domain_name_servers=127.0.0.1"))
+    (no-hook '("hostname")))))
+@end lisp
+@end defvar
+
+@deftp {Data Type} dhcpcd-configuration
+Available @code{dhcpcd-configuration} fields are:
+
+@table @asis
+@item @code{interfaces} (default: @code{()}) (type: list)
+List of networking interfaces---e.g., @code{"eth0"}---to start a DHCP
+client for.  If no interface is specified (i.e., the list is empty) then
+@command{dhcpcd} discovers available Ethernet interfaces, that can be
+configured, automatically.
+
+@item @code{command-arguments} (default: @code{("-q" "-q")}) (type: list)
+List of additional command-line options.
+
+@item @code{host-name} (default: @code{""}) (type: maybe-string)
+Host name to send via DHCP, defaults to the current system host name.
+
+@item @code{duid} (default: @code{""}) (type: maybe-string)
+DHCPv4 clients require a unique client identifier, this option uses the
+DHCPv6 Unique Identifier as a DHCPv4 client identifier as well.  For
+more information, refer to @uref{https://www.rfc-editor.org/rfc/rfc4361, RFC 4361}
+and @code{dhcpcd.conf(5)}.
+
+@item @code{persistent?} (default: @code{#t}) (type: boolean)
+When true, automatically de-configure the interface when @command{dhcpcd}
+exits.
+
+@item @code{option} (default: @code{("rapid_commit" "domain_name_servers" "domain_name" "domain_search" "host_name" "classless_static_routes" "interface_mtu")}) (type: list-of-strings)
+List of options to request from the server.
+
+@item @code{require} (default: @code{("dhcp_server_identifier")}) (type: list-of-strings)
+List of options to require in responses.
+
+@item @code{slaac} (default: @code{"private"}) (type: maybe-string)
+Interface identifier used for SLAAC generated IPv6 addresses.
+
+@item @code{no-option} (default: @code{()}) (type: list-of-strings)
+List of options to remove from the message before it's processed.
+
+@item @code{no-hook} (default: @code{()}) (type: list-of-strings)
+List of hook script which should not be invoked.
+
+@item @code{static} (default: @code{()}) (type: list-of-strings)
+DHCP client can request different options from a DHCP server, through
+@code{static} it is possible to configure static values for selected
+options.  For example, @code{"domain_name_servers=127.0.0.1"}.
+
+@item @code{vendor-class-id} (type: maybe-string)
+Set the DHCP Vendor Class (e.g., @code{MSFT}).  For more information,
+refer to @uref{https://www.rfc-editor.org/rfc/rfc2132#section-9.13,RFC
+2132}.
+
+@item @code{client-id} (type: maybe-string)
+Use the interface hardware address or the given string as a client
+identifier, this is matually exclusive with the @code{duid} option.
+
+@item @code{extra-content} (type: maybe-string)
+Extra content to append to the configuration as-is.
+
+@end table
+@end deftp
+
+
 @cindex NetworkManager
 
 @defvar network-manager-service-type
diff --git a/gnu/services/networking.scm b/gnu/services/networking.scm
index 53840c2764..85ad5287f2 100644
--- a/gnu/services/networking.scm
+++ b/gnu/services/networking.scm
@@ -109,6 +109,24 @@ (define-module (gnu services networking)
             dhcpd-configuration-pid-file
             dhcpd-configuration-interfaces
 
+            dhcpcd-service-type
+            dhcpcd-configuration
+            dhcpcd-configuration?
+            dhcpcd-configuration-interfaces
+            dhcpcd-configuration-command-arguments
+            dhcpcd-configuration-host-name
+            dhcpcd-configuration-duid
+            dhcpcd-configuration-persistent?
+            dhcpcd-configuration-option
+            dhcpcd-configuration-require
+            dhcpcd-configuration-slaac
+            dhcpcd-configuration-no-option
+            dhcpcd-configuration-no-hook
+            dhcpcd-configuration-static
+            dhcpcd-configuration-vendor-class-id
+            dhcpcd-configuration-client-id
+            dhcpcd-configuration-extra-content
+
             ntp-configuration
             ntp-configuration?
             ntp-configuration-ntp
@@ -492,6 +510,149 @@ (define dhcpd-service-type
    (description "Run a DHCP (Dynamic Host Configuration Protocol) daemon.  The
 daemon is responsible for allocating IP addresses to its client.")))
 
+
+;;
+;; DHCPCD.
+;;
+
+(define (serialize-field-name field-name)
+  (let ((str (symbol->string field-name)))
+    (string-replace-substring
+      (if (string-suffix? "?" str)
+        (string-drop-right str 1)
+        str)
+      "-" "")))
+
+(define (dhcpcd-serialize-string field-name value)
+  (if (equal? field-name 'extra-content)
+      #~(string-append #$value "\n")
+      #~(format #f "~a ~a~%" #$(serialize-field-name field-name) #$value)))
+
+(define (dhcpcd-serialize-boolean field-name value)
+  (if value
+    #~(format #f "~a~%" #$(serialize-field-name field-name))
+    ""))
+
+(define (dhcpcd-serialize-list-of-strings field-name value)
+  #~(string-append #$@(map (cut dhcpcd-serialize-string field-name <>) value)))
+
+;; Some fields (e.g. host-name) can be specified with an empty string argument.
+;; Therefore, we need a maybe type to differentiate disabled/empty-string.
+(define-maybe string (prefix dhcpcd-))
+
+(define-configuration dhcpcd-configuration
+  (interfaces
+    (list '())
+    "List of networking interfaces---e.g., @code{\"eth0\"}---to start a DHCP client
+for.  If no interface is specified (i.e., the list is empty) then @command{dhcpcd}
+discovers available Ethernet interfaces, that can be configured, automatically."
+    empty-serializer)
+  (command-arguments
+    (list '("-q" "-q"))
+    "List of additional command-line options."
+    empty-serializer)
+
+  ;; The following defaults replicate the default dhcpcd configuration file.
+  ;;
+  ;; See https://github.com/NetworkConfiguration/dhcpcd/tree/v10.0.10#configuration
+  (host-name
+    (maybe-string "")
+    "Host name to send via DHCP, defaults to the current system host name.")
+  (duid
+    (maybe-string "")
+    "DHCPv4 clients require a unique client identifier, this option uses the DHCPv6
+Unique Identifier as a DHCPv4 client identifier as well.  For more information, refer
+to @uref{https://www.rfc-editor.org/rfc/rfc4361, RFC 4361} and @code{dhcpcd.conf(5)}.")
+  (persistent?
+    (boolean #t)
+    "When true, automatically de-configure the interface when @command{dhcpcd} exits.")
+  (option
+    (list-of-strings
+      '("rapid_commit"
+        "domain_name_servers"
+        "domain_name"
+        "domain_search"
+        "host_name"
+        "classless_static_routes"
+        "interface_mtu"))
+    "List of options to request from the server.")
+  (require
+    (list-of-strings '("dhcp_server_identifier"))
+    "List of options to require in responses.")
+  (slaac
+    (maybe-string "private")
+    "Interface identifier used for SLAAC generated IPv6 addresses.")
+
+  ;; Common options not set in the default configuration file.
+  (no-option
+    (list-of-strings '())
+    "List of options to remove from the message before it's processed.")
+  (no-hook
+    (list-of-strings '())
+    "List of hook script which should not be invoked.")
+  (static
+    (list-of-strings '())
+    "DHCP client can request different options from a DHCP server, through
+@code{static} it is possible to configure static values for selected options.  For
+example, @code{\"domain_name_servers=127.0.0.1\"}.")
+  (vendor-class-id
+    maybe-string
+    "Set the DHCP Vendor Class (e.g., @code{MSFT}).  For more information, refer
+to @uref{https://www.rfc-editor.org/rfc/rfc2132#section-9.13,RFC 2132}.")
+  (client-id
+    maybe-string
+    "Use the interface hardware address or the given string as a client identifier,
+this is matually exclusive with the @code{duid} option.")
+
+  ;; Escape hatch for the generated configuration file.
+  (extra-content
+    maybe-string
+    "Extra content to append to the configuration as-is.")
+
+  (prefix dhcpcd-))
+
+(define (dhcpcd-config-file config)
+  (mixed-text-file "dhcpcd.conf"
+    (serialize-configuration
+      config
+      dhcpcd-configuration-fields)))
+
+(define dhcpcd-account-service
+  (list (user-group (name "dhcpcd") (system? #t))
+        (user-account
+          (name "dhcpcd")
+          (group "dhcpcd")
+          (system? #t)
+          (comment "dhcpcd daemon user")
+          (home-directory "/var/empty")
+          (shell (file-append shadow "/sbin/nologin")))))
+
+(define (dhcpcd-shepherd-service config)
+  (let* ((config-file (dhcpcd-config-file config))
+         (command-args (dhcpcd-configuration-command-arguments config))
+         (ifaces (dhcpcd-configuration-interfaces config)))
+    (list (shepherd-service
+            (documentation "dhcpcd daemon.")
+            (provision '(networking))
+            (requirement '(user-processes udev))
+            (actions (list (shepherd-configuration-action config-file)))
+            (start
+              #~(make-forkexec-constructor
+                    (list (string-append #$dhcpcd "/sbin/dhcpcd")
+                          #$@command-args "-B" "-f" #$config-file #$@ifaces)))
+            (stop #~(make-kill-destructor))))))
+
+(define dhcpcd-service-type
+  (service-type (name 'dhcpcd)
+                (description "Run the dhcpcd daemon.")
+                (extensions
+                 (list (service-extension account-service-type
+                                          (const dhcpcd-account-service))
+                       (service-extension shepherd-root-service-type
+                                          dhcpcd-shepherd-service)))
+                (compose concatenate)
+                (default-value (dhcpcd-configuration))))
+
 
 ;;;
 ;;; NTP.
diff --git a/gnu/tests/networking.scm b/gnu/tests/networking.scm
index e7c02b9e00..7d54ebba50 100644
--- a/gnu/tests/networking.scm
+++ b/gnu/tests/networking.scm
@@ -32,6 +32,7 @@ (define-module (gnu tests networking)
   #:use-module (guix store)
   #:use-module (guix monads)
   #:use-module (guix modules)
+  #:use-module (gnu packages admin)
   #:use-module (gnu packages bash)
   #:use-module (gnu packages linux)
   #:use-module (gnu packages networking)
@@ -44,6 +45,7 @@ (define-module (gnu tests networking)
             %test-inetd
             %test-openvswitch
             %test-dhcpd
+            %test-dhcpcd
             %test-tor
             %test-iptables
             %test-ipfs))
@@ -673,6 +675,110 @@ (define %test-dhcpd
    (description "Test a running DHCP daemon configuration.")
    (value (run-dhcpd-test))))
 
+
+;;;
+;;; DHCPCD Daemon
+;;;
+
+(define %dhcpcd-os
+  (let ((base-os
+          (simple-operating-system
+            (service dhcpcd-service-type
+                     (dhcpcd-configuration
+                       (command-arguments '("--debug" "--logfile" "/dev/console"))
+                       (interfaces '("ens3")))))))
+    (operating-system
+      (inherit base-os)
+      (packages
+        (append (list dhcpcd iproute)
+                (operating-system-packages base-os))))))
+
+(define (run-dhcpcd-test)
+  "Run tests in %dhcpcd-os with a running dhcpcd daemon on localhost."
+  (define os
+    (marionette-operating-system
+     %dhcpcd-os
+     #:imported-modules '((gnu services herd))))
+
+  (define vm
+    (virtual-machine os))
+
+  (define test
+    (with-imported-modules '((gnu build marionette))
+      #~(begin
+          (use-modules (srfi srfi-64)
+                       (gnu build marionette))
+          (define marionette
+            (make-marionette (list #$vm)))
+
+          (define (wait-for-lease)
+            (marionette-eval
+              '(begin
+                 (use-modules (ice-9 popen) (ice-9 rdelim))
+
+                 (let loop ((i 15))
+                   (if (> i 0)
+                     (let* ((port (open-input-pipe "dhcpcd --dumplease ens3"))
+                            (output (read-string port)))
+                       (close-port port)
+                       (unless (string-contains output "reason=BOUND")
+                         (sleep 1)
+                         (loop (- i 1))))
+                     (error "failed to obtain a DHCP lease"))))
+              marionette))
+
+          (test-runner-current (system-test-runner #$output))
+          (test-begin "dhcpcd")
+
+          (test-assert "service is running"
+            (marionette-eval
+             '(begin
+                (use-modules (gnu services herd))
+
+                ;; Make sure the 'dhcpcd' command is found.
+                (setenv "PATH" "/run/current-system/profile/sbin")
+
+                (wait-for-service 'networking))
+             marionette))
+
+          (test-assert "IPC socket exists"
+            (marionette-eval
+              '(file-exists? "/var/run/dhcpcd/ens3.sock")
+              marionette))
+
+          (test-equal "IPC is functional"
+            0
+            (marionette-eval
+              '(status:exit-val
+                 (system* "dhcpcd" "--dumplease" "ens3"))
+              marionette))
+
+          (test-equal "aquires IPv4 address via DHCP"
+            1
+            (and
+              (wait-for-lease)
+              (marionette-eval
+                '(begin
+                   (use-modules (ice-9 popen) (ice-9 rdelim))
+
+                   (let* ((port  (open-input-pipe "ip -4 address show dev ens3"))
+                          (lines (string-split (read-string port) #\newline)))
+                     (close-port port)
+                     (length
+                       (filter (lambda (line)
+                                 (string-contains line "scope global dynamic"))
+                               lines))))
+                marionette)))
+
+          (test-end))))
+  (gexp->derivation "dhcpcd-test" test))
+
+(define %test-dhcpcd
+  (system-test
+   (name "dhcpcd")
+   (description "Test that the dhcpcd obtains IP DHCP leases.")
+   (value (run-dhcpcd-test))))
+
 
 ;;;
 ;;; Services related to Tor

base-commit: 9bc4c9f521caab8aa8d88aa948a650945bb55838

Message #14 received at 75934 <at> debbugs.gnu.org (full text, mbox):

From: Sören Tempel <soeren <at> soeren-tempel.net>
To: Ludovic Courtès <ludo <at> gnu.org>
Cc: Quelln <at> protonmail.com, 873216071 <at> qq.com, 75934 <at> debbugs.gnu.org
Subject: Re: [bug#75934] [PATCH] services: networking: Add dhcpcd service.
Date: Fri, 07 Mar 2025 15:36:19 +0100

Ludovic Courtès <ludo <at> gnu.org> wrote:
> Hi,

Hi Ludo,

Thanks a lot for your feedback!

I just send a v2 which hopefully address all of it.  Most importantly, I
have significantly expanded the documentation, both of the general
service (where I have included a more complex example) and the
individual record type fields.  Moreover, I have hyphened the record
field names as requested and suffixed boolean fields with question
marks.  I have abstained from renaming fields entirely to more easily
map them to dhcpcd's configuration man page, to which I have added
references where appropriate.

> soeren <at> soeren-tempel.net skribis:
> > +    (list '("-q" "-q"))
> 
> Twice?

Yes, this is required to prevent all console output.

See https://man.archlinux.org/man/extra/dhcpcd/dhcpcd.8.en#q

Greetings
Sörens

Message #19 received at 75934-done <at> debbugs.gnu.org (full text, mbox):

From: Ludovic Courtès <ludo <at> gnu.org>
To: soeren <at> soeren-tempel.net
Cc: 75934-done <at> debbugs.gnu.org, Maxim Cournoyer <maxim.cournoyer <at> gmail.com>
Subject: Re: [bug#75934] [PATCH v2] services: networking: Add dhcpcd service.
Date: Sat, 08 Mar 2025 16:10:42 +0100

Hello Sören,

soeren <at> soeren-tempel.net skribis:

> From: Sören Tempel <soeren <at> soeren-tempel.net>
>
> This is intended as an alternative to dhcp-client-service-type as
> isc-dhcp has reached its end-of-life in 2022 (three years ago!),
> see #68619 for more details.  Long-term, this services is therefore
> intended to replace dhcp-client-service-type.
>
> * gnu/services/networking.scm (dhcpcd-service-type): New service.
> (dhcpcd-shepherd-service): New procedure.
> (dhcpcd-account-service): New variable.
> (dhcpcd-config-file): New procedure.
> (dhcpcd-configuration): New record type.
> (dhcpcd-serialize-list-of-strings, dhcpcd-serialize-boolean)
> (dhcpcd-serialize-string): New procedures.
> (serialize-field-name): New procedure.
> * gnu/tests/networking.scm (run-dhcpcd-test): New procedure.
> (%dhcpcd-os, %test-dhcpcd): New variables.
> * doc/guix.texi (Networking Services): Document it.
> ---
> Change since v1:
>
> * Expand documentation and include a larger configuration example
> * Improve record type by hyphening record field names
> * Use make-forkexec-constructor in shepherd service
> * Fix indention of if expression

Great.  Applied, thanks!

Ludo'.

Message #22 received at 75934 <at> debbugs.gnu.org (full text, mbox):

From: Maxim Cournoyer <maxim.cournoyer <at> gmail.com>
To: soeren <at> soeren-tempel.net
Cc: Quelln <at> protonmail.com, ludo <at> gnu.org, 75934 <at> debbugs.gnu.org,
 873216071 <at> qq.com
Subject: Re: bug#75934: [PATCH] services: networking: Add dhcpcd service.
Date: Sun, 09 Mar 2025 11:46:41 +0900

Hi Soeren,

soeren <at> soeren-tempel.net writes:

> From: Sören Tempel <soeren <at> soeren-tempel.net>
>
> This is intended as an alternative to dhcp-client-service-type as
> isc-dhcp has reached its end-of-life in 2022 (three years ago!),
> see #68619 for more details.  Long-term, this services is therefore
> intended to replace dhcp-client-service-type.

I was wondering, why can't this replacement happen *today* ?  The old
dhcp-client-service-type could be marked as deprecated, with
dhcpcd-service-type as a replacement.  The system templates under
gnu/system/examples can then be adjusted to
s/dhcp-client-service-type/dhcpcd-service-type/ and the doc of
dhcp-client-service-type can say it is deprecated via a warning.

Thanks for working on it!

-- 
Thanks,
Maxim

Message #25 received at 75934 <at> debbugs.gnu.org (full text, mbox):

From: Sören Tempel <soeren <at> soeren-tempel.net>
To: Maxim Cournoyer <maxim.cournoyer <at> gmail.com>
Cc: Quelln <at> protonmail.com, ludo <at> gnu.org, 75934 <at> debbugs.gnu.org,
 873216071 <at> qq.com
Subject: Re: bug#75934: [PATCH] services: networking: Add dhcpcd service.
Date: Sun, 09 Mar 2025 11:23:41 +0100

Maxim Cournoyer <maxim.cournoyer <at> gmail.com> wrote:
> Hi Soeren,

Hello Maxim!

> I was wondering, why can't this replacement happen *today* ?

My envisioned timeline was testing the new service a bit first
(gathering feedback from users) and then deprecating the old service.
However, if you think we should deprecate immediately feel free to send
a patch doing that, otherwise I will look into it in the coming weeks.

Further, my thinking was that, considering Guix's review capacities,
splitting this into smaller chunks (adding the package, adding the
service, deprecating the old service, …) makes this easier to review.

Greetings,
Sören

Message #28 received at 75934 <at> debbugs.gnu.org (full text, mbox):

From: Maxim Cournoyer <maxim.cournoyer <at> gmail.com>
To: Sören Tempel <soeren <at> soeren-tempel.net>
Cc: Quelln <at> protonmail.com, ludo <at> gnu.org, 75934 <at> debbugs.gnu.org,
 873216071 <at> qq.com
Subject: Re: bug#75934: [PATCH] services: networking: Add dhcpcd service.
Date: Mon, 10 Mar 2025 08:58:14 +0900

Hi Sören,

Sören Tempel <soeren <at> soeren-tempel.net> writes:

> Maxim Cournoyer <maxim.cournoyer <at> gmail.com> wrote:
>> Hi Soeren,
>
> Hello Maxim!
>
>> I was wondering, why can't this replacement happen *today* ?
>
> My envisioned timeline was testing the new service a bit first
> (gathering feedback from users) and then deprecating the old service.
> However, if you think we should deprecate immediately feel free to send
> a patch doing that, otherwise I will look into it in the coming weeks.
>
> Further, my thinking was that, considering Guix's review capacities,
> splitting this into smaller chunks (adding the package, adding the
> service, deprecating the old service, …) makes this easier to review.

This all makes sense/is reasonable.  I'll wait for you to go through
this.  Thank you for your contributions!

-- 
Maxim

Previous Next

GNU bug tracking system
Copyright (C) 1999 Darren O. Benham, 1997,2003 nCipher Corporation Ltd, 1994-97 Ian Jackson.